投稿日	： 2004/02/25(Wed) 17:45
投稿者	： ak
Ｅメール	：
ＵＲＬ	：
タイトル	： Re^3: ListViewに追加

> レスありがとうございます。
> ヘルプを参照しなくてはいけないのは、十分承知です。
> ですが、なぜかインストールされてないのです・・・
> ネットでもたくさん調べて、試してみたのですが
> 思うように動いてくれません。
>
> 初心者なもので申し訳ありません。
> 教えて頂けないでしょうか？

ヘルプがない・・・

そういう事なら仕方がないですね。

ヘルプは今後の為にも早急に手に入れといた方が良いですよ。

今回のように一覧表示形式で表示したい場合は値を設定する前に
ViewプロパティをlvwListまたはlvwReportに設定しヘッダーを
必要分用意しておく必要があります。

・Viewプロパティ(プロパティウィンドウで設定可)
　0:lvwIcon       :大きいアイコンで表示
　1:lvwSmallIcon　:小さいアイコンで表示
　2:lvwList　　　 :一覧表示
　3:lvwReport     :詳細表示

・ヘッダー設定方法(プロパティウィンドウの列見出しタブで設定可)
　ListView1.ColumnHeaders.Add , , "タイトル"
　必要な列の数だけ指定します。

値の設定方法は
Dim ItmX    As ListItem
    
Set ItmX = ListView1.ListItems.Add("index", "key", "text", "icon", "smallIcon")
ItmX.SubItems(1) = "text"

とりあえずこれで最低限の表示はできるはずです。
他のプロパティに関しては色々試しながらやってみてください。

サンプルを記述しておきますので参考にしてください。

'(*.frm) フォームにListView,TextBox,CommandButtonを各１個配置してください。
Option Explicit

Private Sub Form_Load()
    Dim ii  As Integer
    
    'リストビュー初期設定
    ListView1.View = lvwReport  '詳細表示
    'ヘッダーの設定
    ListView1.ColumnHeaders.Add , , ""
    For ii = 1 To 5
        ListView1.ColumnHeaders.Add , , "SubItems(" & ii & ")"
    Next ii
    
End Sub

Private Sub Command1_Click()
    Dim ii      As Integer
    Dim ItmX    As ListItem
    
    Set ItmX = ListView1.ListItems.Add(, , Text1.Text)
    For ii = 1 To ListView1.ColumnHeaders.Count - 1
        ItmX.SubItems(ii) = ii & " " & Text1.Text
    Next ii

End Sub

★ - ListViewに追加 - イヌ 02/25-15:21No.8127
• Re: ListViewに追加 - ak 02/25-16:28 No.8128
  • Re^2: ListViewに追加 - イヌ 02/25-17:19 No.8130
    • Re^3: ListViewに追加 - ak 02/25-17:45 No.8133
      • Re^4: ListViewに追加 - イヌ 02/26-11:01 No.8141
        • Re^5: ListViewに追加 - イヌ 02/26-11:33 No.8142