投稿日 | : 2002/09/02(Mon) 14:52 |
投稿者 | : 花ちゃん |
Eメール | : |
URL | : |
タイトル | : Re^6: ファイル名の次に日時 |
貴方が取得したのは作成日時です。更新日時なら
Private Sub Form_Load()
With Text1
' .MultiLine = True 別途プロパティで設定して下さい
' .ScrollBars = 3 別途プロパティで設定して下さい
.FontName = "MS ゴシック"
.FontSize = 9
End With
End Sub
Private Sub Command2_Click()
Dim strMyFile() As String
Dim strspcFile As String
Dim kakutyosi As String
Text1.Text = ""
kakutyosi = "spc"
strspcFile = Dir$("h:\FCP\", vbDirectory Or vbHidden Or vbSystem)
Do While strspcFile <> ""
If StrComp(Right$(strspcFile, 3), kakutyosi, 1) = 0 Then
With CreateObject("Scripting.FileSystemObject") _
.GetFile("h:\FCP\" & strspcFile)
'更新時間が要らなければStrCut(.DateLastModified, 10)
Text1.Text = Text1.Text & StrCut(strspcFile, 30) & _
StrCut(.DateLastModified, 20) & vbCrLf
End With
End If
strspcFile = Dir$
Loop
End Sub
Private Function StrCut(ByRef myString As String, _
ByVal LenN As Long) As String
Dim i As Long
Dim j As Long
Dim k As Long
Dim myStringLen As Long
Dim strTemp As String
If LenN < 1 Then myString = "": Exit Function
myStringLen = LenB(StrConv(myString, vbFromUnicode))
If LenN = myStringLen Then '全部半角文字の場合
StrCut = myString
Exit Function
ElseIf myStringLen < LenN Then '文字数が足りない時
StrCut = myString & String$(LenN - myStringLen, " ")
Else
strTemp = "": k = 0
For i = 1 To Len(myString) '文字数(半角換算)のカウント
j = Asc(Mid$(myString, i, 1))
If j >= 0 And j <= 255 Then '半角の場合のカウント
k = k + 1
If k > LenN Then Exit For
strTemp = strTemp & Mid$(myString, i, 1)
Else
k = k + 2 '全角の場合のカウント
If k <= LenN Then
strTemp = strTemp & Mid$(myString, i, 1)
ElseIf k - 1 = LenN Then '漢字分断の処理
strTemp = strTemp & " "
Else
Exit For
End If
End If
Next
StrCut = strTemp
End If
End Function
よねKEN さんのように Tab でもいいかと思ったのですがファイル名の長短が
あると更新日時が揃わなかったので自作のStrCut関数を使用しました。